Emacs定制与扩展

从前只有Emacs server的概念，即可以让已经启动的Emacs进程作为server，然后使用emacsclient连接它；而 Emacs daemon 则是让Emacs进程作为daemon存在。

两者的区别是，Emacs server至少具有一个frame，即使不使用emacsclient程序，我们仍然可以使用这个Emacs进程；而daemon没有任何交互界面存在，必须通过emacsclient创建frame才能使用它。

使用Emacs daemon的好处之一是在重新启动 X Window 的时候无须关闭Emacs进程；另外就是可以远程启动，Emacs daemon可以在登录退出时仍然运行在服务器端。

CVS里面的emacsclient程序拥有两个新的选项： -c 和 -t ，分别用于创建X frame和终端上的frame。

CVS Emacs的另一个特性是可以使用更加漂亮的字体，正是这一特性，使我一直坚持使用 CVS Emacs，而不是正式发布的稳定版本，屏幕截图参见 http://emacs-fu.blogspot.com/2009/01/emacs-23.html 。

编译方法如下：

 cd emacs
 ./configure --prefix=/usr --enable-font-backend
 make bootstrap && make
 sudo make install

设置字体方法是运行 M-x customize-face RET default RET ，我基本都是使用 Liberation Mono 。

因为是开发版，CVS Emacs 难免有这样那样的问题，尤其是对于刚刚开发出来的新特性，但是对于基本特性来说，质量还是相当过硬的，这也是为什么我使用 CVS Emacs 一年多来再也没有回头使用已经发布的稳定版本的原因。如果在使用过程中确信是 CVS Emacs 的问题，建议报到emacs-devel邮件列表上，以便开发者及时发现并解决问题。

在同时使用 Emacs daemon 和漂亮字体的时候我曾遇到过一个问题，至今不得要领，解决方法是很偶然发现的，即将自己的配置全都放在 custom-set-faces 语句之后。我的 .emacs 文件是如下的样子：

(custom-set-variables
  ;; custom-set-variables was added by Custom.
  ;; If you edit it by hand, you could mess it up, so be careful.
  ;; Your init file should contain only one such instance.
  ;; If there is more than one, they won't work right.
 )
(custom-set-faces
  ;; custom-set-faces was added by Custom.
  ;; If you edit it by hand, you could mess it up, so be careful.
  ;; Your init file should contain only one such instance.
  ;; If there is more than one, they won't work right.
 '(default ((t (:inherit nil :stipple nil :background "white"
                :foreground "black" :inverse-video nil :box nil 
                :strike-through nil :overline nil :underline nil 
                :slant normal :weight normal :height 140 :width normal 
                :foundry "unknown" :family "Liberation Mono")))))

(add-to-list 'load-path "~/elisp")
(require 'wl-fedora-init)

eldoc能够在echo area显示函数的参数列表，它对系统自带函数和用户自定义函数一视同仁。例如当输入

 (dolist

的时候，eldoc显示如下帮助信息：

 dolist: ((VAR LIST [[RESULT]]) BODY...)

其中各个参数部分还会随着用户的输入而逐个高亮显示。

paredit是为了对付 Lisp 程序里无处不在的括号，下面列出它的部分功能：

• 在用户输入左括号后，自动输入相应的右括号
• 如果光标在左括号前，那么 C-k 删除整个括号表达式，即使它跨越多行；否则删除到当前一级括号表达式的最后，但保留括号
• M-s 删除当前括号表达式的左右括号
• C-S-) 将当前一级的右括号向右扩展一位，即将下一个表达式包含进来

更多功能参见paredit.el中的变量 paredit-commands 。

使用 find-func ，可以快速定位emacs lisp函数定义，配置如下：

(require 'find-func)
(find-function-setup-keys)

快捷键如下（以下函数由find-func提供，无需自行定义）：

(defun find-function-setup-keys ()
  "Define some key bindings for the find-function family of functions."
  (define-key ctl-x-map "F" 'find-function)
  (define-key ctl-x-4-map "F" 'find-function-other-window)
  (define-key ctl-x-5-map "F" 'find-function-other-frame)
  (define-key ctl-x-map "K" 'find-function-on-key)
  (define-key ctl-x-map "V" 'find-variable)
  (define-key ctl-x-4-map "V" 'find-variable-other-window)
  (define-key ctl-x-5-map "V" 'find-variable-other-frame))

以前都是傻傻地使用 C-h f ，然后把光标移到 *Help* buffer里面的相应链接上，最后按回 车。有了 find-func ，无需移动光标了。摘一段注释

 The funniest thing about this is that I can't imagine why a package so
 obviously useful as this hasn't been written before!!

就我个人来看，Org Mode是近年来最震撼人心的 Emacs Mode 之一，它的出现，使得大量用户更加紧密地团结在Emacs周围。

主页： http://orgmode.org/

代码： git://repo.or.cz/orgmode.git

管理代办事项是Org Mode的核心功能之一，使用起来非常简单。在 Outline Mode 的基础上，Org Mode提供了 C-c C-t 切换任务状态。第一次将人物切换 到 TODO 状态，第二次切换到 DONE 表示完成。下面是一个简单的例子。

 * TODO 写一篇关于Emacs的blog
 * DONE 确认测试全部通过

另外还可以通过 C-c C-s 设置任务开始日期， C-c C-d 设置截止日期。更多功能参见Org Mode手册。

Org Mode 最简单的功能不是管理代办事项，而是记笔记，不需任何配置，就想使 用 Outline Mode 那样即可。除此之外，如果想记录每次记笔记的时间，可以使 用快捷键 C-c ! 来插入一个日期。

Org Mode功能很强大，只是在开始记录的时候稍嫌麻烦，比如要先打开相应的 org文件，选择合适的位置，才能插入内容。如果配合remember使用Org Mode，则 对于那些上下文无关的内容，可以大大减轻辅助工作量。更花哨地，可以配合使 用remember，不仅可以记录日期，还能插入链接。下面是一些配置：

(autoload 'remember "remember" nil t)
(autoload 'remember-region "remember" nil t)
(setq org-reverse-note-order t)
(when (file-exists-p "~/gtd/")
  (define-key global-map [(f8)] 'remember)
  (setq remember-annotation-functions '(org-remember-annotation))
  (setq remember-handler-functions '(org-remember-handler))
  (add-hook 'remember-mode-hook 'org-remember-apply-template)

  (setq org-directory "~/gtd/")
  (setq org-remember-templates
        `((?t "* TODO %?\n  %i"
              ,(expand-file-name "todo.org" org-directory) "Tasks")
          (?m "* %U\n\n  %?%i\n  %a"
              ,(expand-file-name "notes.org" org-directory) "Notes")))

  (let ((todo (expand-file-name "todo.org" org-directory)))
    (when (file-exists-p todo)
      (add-to-list 'org-agenda-files todo))))

想要创建任务，先按 F8 键，然后按 t ，之后输入任务标题、时间、标签或 者更详细的描述，输入完毕之后按 C-c C-c ，将这个任务保存在 ~/gtd/todo.org 文件的 Tasks 大类下面。

只要对任务开始日期稍加修改，Org Mode 就能够管理周期性代办事项。比如周四要开会，可以设置如下代办事项：

 * TODO 开会
 SCHEDULED: <2009-01-22 四>

如果是每周四都开会，就改写成如下的样子：

 * TODO 开会
 SCHEDULED: <2009-01-22 四 +1w>

1w表示每周，另外1d表示每天，1m表示每月。对于周期性的任务， C-c C-t 每次将开始日期修改为相应的下一次开始日期，并保持 TODO 状态不变。

通常情况下，任务开始日期总是严格地按照预定间隔变动，但是当我们需要忽略 掉已经过期的日期时，就可以使用 ++ 或者 .+ 来修饰时间间隔，如

 <2009-01-22 四 ++1w>

的下一次日期一定是今天之后的第一个星期四，而

 <2009-01-22 四 .+1w>

的下一次日期是按今天算起的下一个星期，也就是说，不一定是星期四；如果今天是星期二，那么下一次开始日期就是星期二。

Org Mode本身并没有提供提醒功能，需要配合appt使用。下面是一个简单的配置：

(defun wl-org-agenda-to-appt ()
  ;; Dangerous!!!  This might remove entries added by `appt-add' manually. 
  (org-agenda-to-appt t "TODO"))

(wl-org-agenda-to-appt)
(defadvice  org-agenda-redo (after org-agenda-redo-add-appts)
  "Pressing `r' on the agenda will also add appointments."
  (progn
    (let ((config (current-window-configuration)))
      (appt-check t)
      (set-window-configuration config))
    (wl-org-agenda-to-appt)))

(ad-activate 'org-agenda-redo)

在 Org Mode 的 Agenda View 下，按 r 或者 g ，就可以把有具体时间的 任务添加到appt的任务提醒列表里面。需要注意的是，手工使用 appt-add 添 加的提醒将被清除，无法恢复。所以，当使用本节的配置时，请将任务添加到相 应的org文件里，而不是使用 appt-add 。

经过配置，filecache 能够根据用户输入的文件名，找到该文件的实际位置，省 去了用户回忆和查找的过程。下面是我的配置（忽略git相关目录及文件）：

(require 'filecache)
(add-to-list 'file-cache-filter-regexps "\\.git\\>")
(file-cache-add-directory-recursively "/path/to/project")

filecache 没有独立的文档，用法记录在源文件头上的注释里，不过已经足够 了，本来也不是很复杂的东西。使用时有一个小窍门，在使用 C-x C-f 打开文 件时，不用管前面的目录名是什么，直接在后面输入文件名，然后用 C-TAB 补 全，目录名会自动被替换，无需手工修改。

使用filecache可以快速打开项目里的某个文件，但是它的文件名补全功能有一个小小的 局限，就是必须从头开始匹配，不像iswitchb那样可以匹配buffer名的任意部分。配合使 用anything可以解决这个问题。

anything不仅仅可以配合filecache使用，之所以叫anything，就是因为它可以快速打开 anything，而且高度可配置、可扩展。在anything模式下有几个快捷键，左右方向键在不 同分类之间切换； C-n 和 C-p 在不同条目之间切换； C-v 和 M-v 上下翻页。下面是我的配置， 使用 F9 作为快捷键启动anything模式。

(eval-after-load 'anything
  '(progn
     (setq anything-enable-digit-shortcuts t)
     (global-set-key (kbd "<f9>") 'anything)))

(eval-after-load 'anything-config
  '(add-to-list 'anything-sources anything-c-source-file-cache))

(require-maybe 'anything)
(require-maybe 'anything-config)

hippie-expand是个非常强大的补全工具，虽然其中的补全文件或路径功能很少用 到，但是在添加 load-path 的时候就很方便了，感觉就像在mini-buffer里输 入路径一样。当然用得最多的还是在写程序的时候了。使用下面的配置可以通过 M-/ 快捷键调用该补全功能。：

(global-set-key (kbd "M-/") 'hippie-expand)

(setq hippie-expand-try-functions-list
      '(try-expand-all-abbrevs try-expand-dabbrev
        try-expand-dabbrev-all-buffers try-expand-dabbrev-from-kill
        try-complete-lisp-symbol-partially try-complete-lisp-symbol
        try-complete-file-name-partially try-complete-file-name))

auto-complete.el提供了与hippie-expand完全不同的补全方式，通过弹出菜单的 形式让用户在候选列表中选择，它的作者用一段视频展示了auto complete提供怎 样的功能。

以下配置，使用 F1 键打开自动补全功能，补全过程中候选列表随着输入的变 化随之更新，选择或取消后，自动补全功能关闭。：

(require-maybe 'auto-complete)
(eval-after-load 'auto-complete
  '(progn
     (global-auto-complete-mode t)
     (define-key ac-complete-mode-map "\C-n" 'ac-next)
     (define-key ac-complete-mode-map "\C-p" 'ac-previous)
     (setq ac-auto-start nil)
     (defun wl-ac-start ()
       (interactive)
       (setq ac-auto-start 6)
       (ac-start))
     (defadvice ac-cleanup (after wl-ac-cleanup ())
       (setq ac-auto-start nil))
     (ad-activate 'ac-cleanup)
     (define-key global-map (kbd "<f1>") 'wl-ac-start)
     (add-hook 'emacs-lisp-mode-hook
               (lambda ()
                 (make-local-variable 'ac-sources)
                 (setq ac-sources
                       '(ac-source-words-in-buffer ac-source-symbols))))

     (defvar ac-source-etags
       '((candidates
          . (lambda () (all-completions ac-target (tags-completion-table))))))
     (defun wl-add-ac-source-etags ()
       (make-local-variable 'ac-sources)
       (add-to-list 'ac-sources 'ac-source-etags))

     (add-hook 'c-mode-common-hook 'wl-add-ac-source-etags)))